| T O P I C R E V I E W |
| VpV |
Posted - 18 October 2010 : 11:26:12
di Oliver Seban.
Buon dì, scusate, c'è nessuno che è riuscito a fare l'indicatore in questione con il linguaggio di Insider ?
Ho visto che degli utenti di Visual Trader son riusciti nella conversione, utilizzando il CCI.
Grazie per chi vorrà aiutarmi, compreso anche il supporto tecnico anche se non è dovuto in questa sezione.
 |
| 9 L A T E S T R E P L I E S (Newest First) |
| SupportoTecnico |
Posted - 25 October 2010 : 15:31:38
Dimenticavo... per chi possiede la versione 3 di Insider 3000 e volesse passare alla 4 ovviamente saranno previsti degli incentivi.  |
| SupportoTecnico |
Posted - 25 October 2010 : 15:18:13
La versione di Insider 3000 attualmente in lavorazione non rientrerà nella versione 3. Sarà infatti la 4. Non si tratta quindi di un semplice aggiornamento. In effetti la 3 ha ormai molti anni ed è arrivato il momento di guardare avanti. Migliorando.
Sicuramente non toglieremo nulla al programma a livello di funzionalità per inseguire gli effetti speciali. Certo, un cambiamento grafico ci sarà anche, ma lungi dal peggiorare le caratteristiche del programma.
Su questo si può stare tranquilli. Ci saranno molte aggiunte e specialmente un modo diverso di lavorare.
La parte di programmazione trading system e indicatori, e di esplorazione titoli ad esempio sarà parecchio potenziata.
Ma è ancora troppo presto per elencare le molte novità. Siamo ancora molto lontani dal rilascio effettivo (che avverrà speriamo almeno in parte entro il 2011).
|
| VpV |
Posted - 25 October 2010 : 10:59:19
quote:
Originally posted by SupportoTecnico
Al momento non è possibile impostare il colore di un indicatore in modo da suddividere le fasi positive da quelle negative.
Sarà sicuramente una delle implementazioni future.
Colgo l'occasione per dire che ci stiamo concentrando già da un anno sulla nuova versione di Insider 3000, che non sarà un semplice restyling della versione attuale, ma una vera e propria rivoluzione. Uno stacco molto netto dall'Insider 3000 attuale.
Buon dì,
In riferimento a quanto scritto mi preme chiedervi:
1° tale versione rientra sempre nella versione 3. oppure sarà totalmente nuova ? chiedo questo perchè ho acquistato il programma nei mesi precedenti, basandomi anche sugli aggiornamenti e da quello che dite sembra essere una versione totalmente nuova. Sarà quindi liberamente scaricabile dai possessori dell'attuale varsione ?
2° Come fruitore, attualmente, soddisfatto del programma Vi chiedo di "aggiungere" e non togliere al programma stesso; Vi dico questo perchè il programma è già ottimo così e il rischio di perdere ciò che c'è di buono è alto (visto in altri casi).
Per me Insider è quel programma che si pone tra la prg in excel/opencalc o + semplicemente di foglio elettronico classico e quella più semplice e stringente offerta dalle varie piatte o programmi vari.
Se si può dire, un misto tra "programmazione a basso e alto livello".
Il mio è solo un giudizio da utilizzatore che ha comprato il prodotto e lo ha scelto per il motivo sopra, oltre ovviamente al rapporto prezzo/offerta/qualità.
Mi auguro che l'inseguire i "colori, le trasparenze, gli sfondi" e via dicendo non implichi la perdita della "spina dorsale" che ha questo Vostro programma.
Solo un pensiero e giudizio di un Vostro cliente, niete più.
Buon lavoro. |
| SupportoTecnico |
Posted - 23 October 2010 : 15:31:06
Al momento non è possibile impostare il colore di un indicatore in modo da suddividere le fasi positive da quelle negative.
Sarà sicuramente una delle implementazioni future.
Colgo l'occasione per dire che ci stiamo concentrando già da un anno sulla nuova versione di Insider 3000, che non sarà un semplice restyling della versione attuale, ma una vera e propria rivoluzione. Uno stacco molto netto dall'Insider 3000 attuale.
|
| VpV |
Posted - 22 October 2010 : 15:27:10
[quote]Originally posted by SupportoTecnico
Ecco una prima bozza dell'indicatore SuperTrend scritto nel linguaggio di Insider 3000. Prova a testarlo, partendo da un confronto con il SuperTrend di altre applicazioni, e a vedere se corrisponde veramente a livello di grafico.
[code]
Buon pomeriggio, allora grazie ancora e Vi posso dire che il risultato è quasi del tutto simile all'originale, differenze, per ora, apparentemente trascurabili. Mi riservo del tempo per confermare.
Approfitto per chiedervi, visto che sul manuale non ho travato ancora un riferimento, se in Insider è presente l'opzione di colorare la curva quando è maggiore e minore del valore in esame.
In sintesi quando l'indicatore è maggiore della curva in esame esso sarà rosso, mentre sarà verde quando sarà sotto.
Grazie ancora. |
| VpV |
Posted - 21 October 2010 : 11:47:33
[quote]Originally posted by SupportoTecnico
Ecco una prima bozza dell'indicatore SuperTrend scritto nel linguaggio di Insider 3000. Prova a testarlo, partendo da un confronto con il SuperTrend di altre applicazioni, e a vedere se corrisponde veramente a livello di grafico.
Grazie, sempre molto gentili e rapidi. Provo il listato e poi vi faccio sapere.
|
| SupportoTecnico |
Posted - 20 October 2010 : 13:08:03
Ecco una prima bozza dell'indicatore SuperTrend scritto nel linguaggio di Insider 3000. Prova a testarlo, partendo da un confronto con il SuperTrend di altre applicazioni, e a vedere se corrisponde veramente a livello di grafico.
dim trend as Numeric = 0
dim bandadn_prec as Numeric = 0
dim bandaup_prec as Numeric = 0
Property Moltiplicatore as Numeric
Default (3)
EndProperty
Property Nm_periodi as Numeric
Default (100)
EndProperty
Function Main()
dim volatilita as Numeric
dim prezzomediano as Numeric
dim bandaup as Numeric
dim bandadn as Numeric
dim supertrend as Numeric = 0
'CALCOLO DELLA VOLATILITA '
'La volatilità è calcolata sull'ATR di 100 periodi
volatilita = ATR(Nm_periodi)
'CALCOLO DEL PREZZO MEDIANO
'Il prezzo mediano è rappresentato da massimo + minimo diviso due
prezzomediano = (High + Low) / 2
'CALCOLO DELLE BANDE
'la banda up è corrispondente al prezzomediano + moltiplicatore x atr
'la banda down è corrispondente al prezzo mediano - moltiplicatore x atr
'Nota il moltiplicatore standard è solitamente impostato a 3
bandaup = prezzomediano + (moltiplicatore * volatilita)
bandadn = prezzomediano - (moltiplicatore * volatilita)
if (trend = 0) then
bandadn_prec = bandadn
bandaup_prec = bandaup
trend = 1
endif
'CASO 1
'Se il trend = 1 e il close è inferiore alla banda down allora il trend
'diventa negativo, il calcolo della banda diventa quello standard e la
'supertrend assume l 'aspetto della banda superiore in quanto il trend
'è diventato negativo.
if (trend = 1) and (Close < bandadn_prec) then
trend = - 1
bandaup = prezzomediano + (moltiplicatore * volatilita)
supertrend = bandaup
endif
'CASO 2
'Se il trend = 1 e il close è maggiore o uguale della banda down e la bandadown
'è inferiore alla bandadown precedente, il trend rimane sempre positivo ma
'la bandadown rimane sempre allo stesso livello e non scende.
'Il concetto principale è che nel caso in cui il trend è positivo una volta
'determinata la prima volta la bandadown, quest 'ultima puo' solo salire ad
'inseguimento(in una sorta di trailing stop) .
if (trend = 1) and (Close >= bandadn_prec) and (bandadn < bandadn_prec) then
bandadn = bandadn_prec
supertrend = bandadn
endif
'CASO 3
'Se il trend = 1 e il close è maggiore o uguale della banda down e la banddown
'è maggiore della bandadown precedente, il trend rimane sempre positivo ma
'la supertrend assume lo stesso livello della bandadown in maniera che il
'limite della banda inferiore si alza ad inseguimento
if (trend = 1) and (Close >= bandadn_prec) and (bandadn >= bandadn_prec) then
supertrend = bandadn
endif
'CASO 4
'Se il trend è negativo e il close risulta maggiore della bandaup allora il
'trend diventa positivo, il calcolo della banda diventa quello standard e la
'supertrend assume l 'aspetto della banda inferiore in quanto il trend è
'diventato positivo
if (trend = - 1) and (close > bandaup_prec) then
trend = 1
bandadn = prezzomediano - (moltiplicatore * volatilita)
supertrend = bandadn
endif
'CASO 5
'Se il trend è negativo e il close risulta inferiore uguale alla bandaup e la
'bandaup risulta maggiore della bandaup precedente allora il trend rimane
'sempre negativo e la bandaup rimane sempre allo stesso livello.
'Il concetto è che se il trend è negativo la banda superiore, una volta fissata
'puo' solo scendere ad inseguimento come in una sorta di trailing stop.
if (trend = - 1) and (close <= bandaup) and (bandaup > bandaup_prec) then
bandaup = bandaup_prec
supertrend = bandaup
endif
'CASO 6
'Se il trend è negativo e il close risulta inferiore uguale alla bandaup e la
'bandaup risulta inferiore della banda precedente allora la supertrend assume
'il nuovo valore della bandaup
if (trend = - 1) and (close <= bandaup) and (bandaup <= bandaup_prec) then
supertrend = bandaup
endif
bandaup_prec = bandaup
bandadn_prec = bandadn
return supertrend
Endfunction
|
| VpV |
Posted - 19 October 2010 : 16:37:54
quote:
Originally posted by SupportoTecnico
La cosa pare interessante. Intanto comincerei a postare come va costruito l'indicatore, e cioè la sua formula, le sue regole ecc.. insomma tutto quello che può servire ad implementarlo.
Ho trovato questo su un forum. Tutti hanno avuto lo stesso problema, sia chi usa V.T, excel(VB) e via dicendo. Il codice non era disponibile, è stato dedotto.
Comunque questo è un esempio di quello che sono riusciti a fare in V.T.
------------------------------------------------------------
{******************************************************************************
* SUPERTREND by ender85
* Codice di Robom1 preso dal Fol e modificato in minima parte
* solo per renderlo simile alla versione di Prorealtime
* Ringraziamenti: Robom1, Damien e Ronzy
******************************************************************************}
Var: volatilita(0),
prezzomediano(0),
bandaup(0),
bandadn(0),
trend(0),
supertrend(0),
colore(0),
inizio(0);
input: Moltiplicatore(3),
Nm_periodi(100);
//******************************************************************************
//CALCOLO DELLA VOLATILITA'
//La volatilità è calcolata sull'ATR di 100 periodi
volatilita = ATR(C, Nm_periodi);
//******************************************************************************
//CALCOLO DEL PREZZO MEDIANO
//Il prezzo mediano è rappresentato da massimo + minimo diviso due
prezzomediano = (H + L) / 2;
//******************************************************************************
//CALCOLO DELLE BANDE
//la banda up è corrispondente al prezzomediano + moltiplicatore x atr
//la banda down è corrispondente al prezzo mediano - moltiplicatore x atr
//Nota il moltiplicatore standard è solitamente impostato a 3
bandaup = prezzomediano + (moltiplicatore * volatilita);
bandadn = prezzomediano - (moltiplicatore * volatilita);
//******************************************************************************
//INIZIALIZZAZIONE TREND A 1 CON ESAME PRIMA BARRA (non necessario se iniz. la var.
if inizio = 0 then trend = 1; inizio = 1; endif;
//******************************************************************************
//CASO 1
//Se il trend = 1 e il close è inferiore alla banda down allora il trend
//diventa negativo, il calcolo della banda diventa quello standard e la
//supertrend assume l'aspetto della banda superiore in quanto il trend
//è diventato negativo.
if trend = 1 and
C < bandadn[1]
then
trend = -1;
bandaup = prezzomediano +
(moltiplicatore * volatilita);
supertrend = bandaup;
endif;
//******************************************************************************
//CASO 2
//Se il trend = 1 e il close è maggiore o uguale della banda down e la bandadown
//è inferiore alla bandadown precedente, il trend rimane sempre positivo ma
//la bandadown rimane sempre allo stesso livello e non scende.
//Il concetto principale è che nel caso in cui il trend è positivo una volta
//determinata la prima volta la bandadown, quest'ultima puo' solo salire ad
//inseguimento (in una sorta di trailing stop).
if trend = 1 and
C >= bandadn[1] and
bandadn < bandadn[1]
then
bandadn = bandadn[1];
supertrend = bandadn;
endif;
//******************************************************************************
//CASO 3
//Se il trend = 1 e il close è maggiore o uguale della banda down e la banddown
//è maggiore della bandadown precedente, il trend rimane sempre positivo ma
//la supertrend assume lo stesso livello della bandadown in maniera che il
//limite della banda inferiore si alza ad inseguimento
if trend = 1 and
C >= bandadn[1] and
bandadn >= bandadn[1]
then
supertrend = bandadn;
endif;
//******************************************************************************
//CASO 4
//Se il trend è negativo e il close risulta maggiore della bandaup allora il
//trend diventa positivo, il calcolo della banda diventa quello standard e la
//supertrend assume l'aspetto della banda inferiore in quanto il trend è
//diventato positivo
if trend =-1 and
close > bandaup[1]
then
trend = 1;
bandadn = prezzomediano -
(moltiplicatore * volatilita);
supertrend = bandadn;
endif;
//******************************************************************************
//CASO 5
//Se il trend è negativo e il close risulta inferiore uguale alla bandaup e la
//bandaup risulta maggiore della bandaup precedente allora il trend rimane
//sempre negativo e la bandaup rimane sempre allo stesso livello.
//Il concetto è che se il trend è negativo la banda superiore, una volta fissata
//puo' solo scendere ad inseguimento come in una sorta di trailing stop.
if trend =-1 and
close <= bandaup and
bandaup > bandaup[1]
then
bandaup = bandaup[1];
supertrend = bandaup;
endif;
//******************************************************************************
//CASO 6
//Se il trend è negativo e il close risulta inferiore uguale alla bandaup e la
//bandaup risulta inferiore della banda precedente allora la supertrend assume
//il nuovo valore della bandaup
if trend =-1 and
close <= bandaup and
bandaup <= bandaup[1]
then
supertrend = bandaup;
endif;
//******************************************************************************
//Colora il Supertrend a seconda che il trend sia positivo (1) o negativo (-1)
if trend = 1 then
colore= green;
else
colore= red;
endif;
//******************************************************************************
//Disegno il Supertrend
PlotChart(supertrend, 0, colore, solid, 3); |
| SupportoTecnico |
Posted - 19 October 2010 : 14:05:45
La cosa pare interessante. Intanto comincerei a postare come va costruito l'indicatore, e cioè la sua formula, le sue regole ecc.. insomma tutto quello che può servire ad implementarlo. |
|
|
